Back to EDS Strategies

 

 

ADX_RSI

PRICEFilter if [Close]>10.00 and [Close]<50.00.
VOLFilter if [Volume]>300.
MONEYFLOWgood if Slope([MnyFlow], 15)>0.
CLOSEgood if [Close]<[ST MA] and [Close]<[ST ESA] and [Close]<[IT MA] and [Close]<[LT MA].

ADXgoodBUY if [ADX]>20. 

RSIgoodBUY if [RSI Wilder]<32 and [RSI Wilder]+Val([RSI Wilder], 1)
+Val([RSI Wilder], 2)+Val([RSI Wilder], 3)
+Val([RSI Wilder], 4)< Val([RSI Wilder],1)
+Val([RSI Wilder], 2)+Val([RSI Wilder], 3)
+Val([RSI Wilder], 4)+Val([RSI Wilder], 5).

ADX_RSIBUY if PRICEFilter and VOLFilter and RSIgoodBUY and CLOSEgood and MONEYFLOWgood and ADXgoodBUY.

ADX_RSISELL if UPPERBBcrossDOWN and ADXgoodSELL and RSIgoodSELL. 

ADXgoodSELL if [ADX]>=20.
RSIgoodSELL if [RSI Wilder]+Val([RSI Wilder], 1)+Val([RSI Wilder], 2)+Val([RSI Wilder], 3)+Val([RSI Wilder], 4)
<Val([RSI Wilder], 1)+Val([RSI Wilder], 2)+Val([RSI Wilder], 3)+Val([RSI Wilder], 4)+VAL([RSI Wilder],5). 

! Price crosses from above to below Upper BB
UPPERBBcrossDOWN if VAL([close],1)>VAL([Upper BB],1) and [Upper BB]>[close].

! Price crosses from below to above Lower BB
LOWERBBcrossUP if VAL([close],1)<VAL([Lower BB],1) and [Lower BB]<[close].

!!!Example stock AXP on 09/07/2001

Return to Top of Page

Bollinger Bands squeeze and low volatility

! Bollinger Bands tighten with low volatility

Bbandsqueze if Slope([Lower BB],5) > 0 and Slope([Upper BB],5) < 0 and LoVal([Volatility],21)=[Volatility].

!!!Example stock UN on 06/01/2001

Return to Top of Page

ER Down and decreasing trendscore

! Rule - if we have a Down rating and a change in DTS in the last 5 days
! make sure DTS didn't wipsaw the other way too.

DownERwDTS5 if [er down] >= 90 and loval([dts],5) <= -80 and [ts] < 0.

! Rule - if we have a change in DTS and an ER in the last 5 days

DTSwDownER5 if [DTS] <= -80 and HiVal([er down],5) >= 90.

! Sell when if either of the above rules

ConfirmedDown if DownERwDTS5 or DTSwDownER5.

!!!Example stock Q on 09/07/2001

Return to Top of Page

ER Up and increasing trendscore

! Rule - if we have an Up rating and a change in DTS in the last 5 days
! make sure DTS didn't wipsaw the other way too.

UpERwDTS5 if [er up] >= 90 and hival([dts],5) >= 80 and [ts] > 0.


!Rule - if we have a change in DTS and an ER in the last 5 days
DTSwUpER5 if [DTS] >= 80 and HiVal([er up],5) >= 90.

! Buy when if either of the above rules

ConfirmedUp if UpERwDTS5 or DTSwUpER5.

!!!Example stock BBY on 09/07/2001

Return to Top of Page

OBV Pct and VA Pct are negative

! Many times you will find that when the OBV Percentage and
! the Volume Accumulation Percentage are in sync, the resulting
! signal is far more powerful. When both are positive it is a buy signal,
! and when both are negative it is a sell signal. 
! OBVPct anad VAPct are negative

OBVPctVAPctneg if [OBV Pct]<0 and [VA Pct]<0.

!!!Example stock AA on 09/07/2001

Return to Top of Page

OBV Pct and VA Pct are positive

! Many times you will find that when the OBV Percentage and
! the Volume Accumulation Percentage are in sync, the resulting
! signal is far more powerful. When both are positive it is a buy signal,
! and when both are negative it is a sell signal. 
! OBVPct anad VAPct are positive

OBVPctVAPctUP if [OBV Pct]>0 and [VA Pct]>0.

!!!Example stock XEL on 09/07/2001

Return to Top of Page

Volume and volatility filter

!!!!!!!!!Volume Filters!!!!!!!!!!!!!!!

VolumeNot0 if [Volume] > 0.
VolumeNot1000x if [Volume] < [Volume ESA] * 1000.
EnoughVol if [Volume ESA] > 200.

VolumeOk if VolumeNot0 and VolumeNot1000x and EnoughVol.

!!!!!!!!!!!!Price Filters!!!!!!!!!!!!!!!

OKTrade if [close] > 2.
NotTooVolatile if [Volatility] < [Volatility MA] * 1.5 and [Volatility] < 80.

PriceOk if OKTrade and NotTooVolatile.

TradeOK if PriceOk and VolumeOk.

!!!Example stock FRX on 09/07/2001

Return to Top of Page

Volume spike and price change

! Alert us if we have volume spikes and good price movements

! 25% volume spike
VolumeSpike if [volume] >= [volume esa] * 1.25.

! closed up if higher than previous days high
ClosedUp if [close] >= Val([high],1).

!Closed down if lower than previous days low
ClosedDown if [close] <= Val([low],1).

SpikedUp if VolumeSpike and ClosedUp.

!!!Example stock XEL on 09/07/2001


SpikedDown if VolumeSpike and ClosedDown.

!!!Example stock DAL on 09/07/2001

Return to Top of Page